# 1 "/u/exp/stan/nmr/lists/pp/hncof.s"
;hncof.fa
;3D HNCO - with Watergate reverse INEPT (FHSQC) and minimal H2O saturation.
;This version makes use of the gp gradient syntax.
;Kay, Xu, and Ymazaki, J. Magn. Reson. A 10l, 129-133 (1994)
;Mori et al., J. Magn. Reson. B 108, 94-98 (1995)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncof.fa,v 1.8 2002/02/07 01:10:16 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm,
;o3p: use fq3list fahncof.C (175ppm,56ppm)
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p11 90 2.0 ms H1 semi-selective H2O flip-back pulse at power:
;  1) pl21 (zgsel1.fa), with phcor21;
;  2) pl22 (zgsel2.fa), with phcor22.
;  Check for a possible phase difference between hard H1 and soft H1
;  pulses and set phcor21 and phcor22 accordingly.
;p10 90 H at pl10 (H1 composite decoupling)
;p2 90 N at pl2. If p5/2 > p2 define SHORT_P2 below.
;p3 90 CO at pl3 
;   semi-selective: p90=sqrt(15)/(4*dNu), dNu=(175ppm-55ppm)*bf3); 64.4us at 500MHz
;p5 180 Ca square shaped (spnam5) at power sp5, offset Ca-CO (-120ppm)
;   semi-selective: p180=sqrt(3)/(2*dNu), dNu=(175ppm-55ppm)*bf3); 57.6us at 500MHz
;p8 180 CO square shaped (spnam8) at power sp8, offset CO-Ca (120ppm)
;   semi-selective: p180=sqrt(15)/(2*dNu), dNu=(175ppm-55ppm)*bf3); 128.8us at 500MHz
;pl0 120dB
;d21: 1/(2*dNu), dNu=(ChSh(NH)-ChSh(H2O))*bf1, 300us at 500MHz
;
;H1  Waltz-16x or DIPSI-2x (cpdprg1), using p90 (PCPD) at pl10
;N15 Waltz-16 (cpdprg2), 90 dgr pulse (PCPD) at pl12
;Ca  on-resonance SEDUCE1 decoupling of Ca, using p90 (PCPD) at sp3,
;    shape seduce1, offset 0, cpdprg3 waltz16sp3.
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 35-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  N15 chemical shift axis has reverse orientation
;C13 evolution:
;  in0, SW(C)=1/(2*in0), typ. 15 ppm
;  l6 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  C' chemical shift axis is OK
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for triple-axis (single-axis) gradients:
;gpz1:  15% (15%)
;gpz2:   6% (6%)
;gpz3:  15% (15%)
;gpz4:  -8% (-8%)
;gpz5:  15% (15%)
;gpz6:  12% (12%)
;gpx7:  54%, adjust for magic-angle (0%)
;gpz7:  30% (55%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.50
;gpnam6: sine.50
;gpnam7: sine.100
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment


;#define SHORT_P2	; uncomment if p5/2 > p2


;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:



;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
# 99 "/u/exp/stan/nmr/lists/pp/hncof.s"

;
;
define delay TAUA
define delay TAUA2
define delay TAUA7
define delay TAUB
define delay TAUC
define delay TAUW
define delay TAUW1
define delay CEN_HN1
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_180
define pulse CO_90
define pulse CO_180
define pulse CAO_180
define pulse COA_180

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=40u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CO_90=p3"
"CO_180=CO_90*2"
"CAO_180=p5"
"COA_180=p8"

"GRAD1=700u"
"GRAD2=500u"
"GRAD3=1.0m"
"GRAD4=1.0m"
"GRAD5=600u"
"GRAD6=500u"
"GRAD7=700u"

"d6=H1_90"
"TAUW=d21"
"TAUW1=(TAUW/2)-N15_90"
"TAUA=2.3m"
"TAUA2=TAUA-GRAD2-d13-d16"
"TAUA7=TAUA-TAUW*2.5-H1_90*2.385-GRAD7-d16-d13"
"TAUB=5.4m"
"TAUC=12.4m"
"d24=TAUC-TAUB-p10-d13*2-d12"
"d10=12.4m"
"d30=12.4m-TAUB-COA_180-p10-d12*3-d13*5"



 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-N15_180-d12*2-d13*2)/2"
# 172 "/u/exp/stan/nmr/lists/pp/hncof.s"



"CEN_HN1=N15_90-H1_90"










  "d31=2*(TAUA2+GRAD2+TAUB+TAUA7+GRAD7+2*TAUW+TAUW1)+GRAD1+GRAD3+TAUC+GRAD4+GRAD5+GRAD6"




# 1 "/u/exp/stan/nmr/lists/pp//Avance.incl"
;Avance.incl
;
;version  99/08/02





























# 191 "/u/exp/stan/nmr/lists/pp/hncof.s"

# 1 "/u/exp/stan/nmr/lists/pp//Grad.incl"
;Grad.incl  -  include file for Gradient Spectroscopy
;avance-version
;version 99/02/19
















define list<gradient> EA=<EA>
# 192 "/u/exp/stan/nmr/lists/pp/hncof.s"

1 ze
2 d13 do:f2
  d11 setnmr2^0
  d14
3 d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d14


# 1 "/u/exp/stan/nmr/lists/pp//faexptcorr.incl"
; This is here to trick "expt" to calculate the experiment time
; correctly.
  if "1 == 1" goto nod31
  d31
nod31, d13
# 210 "/u/exp/stan/nmr/lists/pp/hncof.s"

  d1 pl1:f1 pl2:f2
;-------------------- set carbon freq. on CO ---------------
  50u fq3:f3
  d13 setnmr2|0
  d13 setnmr0|34
  (N15_90 ph0):f2
  d13
  GRAD1:gp1		;400u, 10G/cm
  d16 pl3:f3
;--------------------- INEPT to f2 --------------------------
  (H1_90 ph0):f1
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):f1 (N15_180 ph0):f2
  TAUA2
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  (H1_90 ph1):f1
  d13
  d12 pl22:f1
  (H1_S90 ph22:r):f1	;2ms 90 H1 pulse at phase x
  d13
  GRAD3:gp3		;1.0m, 10G/cm
  d16
;----------------- INEPT to f3' and refocus H ---------------
  (N15_90 ph11):f2
  TAUB
  d13 \n d12 pl10:f1 \n p10:f1 ph1 \n d13 cpds1:f1
  d24
  (N15_180 ph0):f2
  (TAUC) (d13 CO_180 ph0):f3
  (N15_90 ph0):f2
  d13 do:f1 \n p10:f1 ph3 \n d13 \n d12 pl1:f1
  d13
  GRAD4:gp4		;1.0m, -5G/cm
  d16
;----------------------- f3' evolution ------------------------
  (CO_90 ph12):f3
  d13

  d12 pl0:f3

  (d0 CAO_180:sp5 ph0):f3
  (d13 N15_180 ph0 d0):f2
  d12 pl3:f3
# 263 "/u/exp/stan/nmr/lists/pp/hncof.s"


  (CO_90 ph0):f3
  d13
  GRAD5:gp5		;600u, 10G/cm
;--------------------- Switch f3 frequency to Ca --------------
  d16 fq3:f3
  d12 pl0:f3
  d13 \n d12 pl10:f1 \n p10:f1 ph1 \n d13 cpds1:f1 
  d13 \n d12 pl0:f3 \n d13 cpds3:f3
;------ Refocus f3' and constant time evolution on N (t2) -----
  (N15_90 ph14):f2
  d10
  (N15_180 ph15):f2
  d13 do:f3
  d12 pl0:f3
  (COA_180:sp8 ph0):f3
  d13 \n d12 pl0:f3 \n d13 cpds3:f3
  d30
  d13 do:f1 \n p10:f1 ph3 \n d13 \n d12 pl1:f1
  TAUB
  (N15_90 ph0):f2
  d13 do:f3
  d13
  GRAD6:gp6		;500u, 8G/cm
  d16 pl21:f1
  (H1_S90 ph21:r):f1	;2ms 90 H1 pulse at phase x
  d13
  d12 pl1:f1
  (H1_90 ph2):f1
  d13
  TAUA7
  GRAD7:gp7		;700u, 40G/cm
  d16
  (H1_90*0.231 ph1):f1
  TAUW
  (H1_90*0.692 ph1):f1
  TAUW
  (H1_90*1.462 ph1):f1
  TAUW1
  (N15_180 ph0):f2
  TAUW1
  (H1_90*1.462 ph3):f1
  TAUW
  (H1_90*0.692 ph3):f1
  TAUW
  (H1_90*0.231 ph3):f1
  d13
  GRAD7:gp7		;700u, 40G/cm
  d16 pl12:f2
  TAUA7
  d6 setnmr0^34
  go=2 ph31 cpds2:f2

# 319 "/u/exp/stan/nmr/lists/pp/hncof.s"

  d11 do:f2 wr #0 if #0 zd

  d13 setnmr2^0

  d14 ip14
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
# 335 "/u/exp/stan/nmr/lists/pp/hncof.s"


  d14 ip12
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6


exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0 0 0 0 2 2 2 2
ph14=0
ph15=0 0 2 2
ph16=0
ph21=0
ph22=0
ph31=0 2 0 2 2 0 2 0

