#!/bin/csh

#
# 4D 13C NOE Processing with re-ordering of the data dimensions: 
#   Original order: X=acq1H Y=indir1H Z=13Cz    A=13Ca.
#   Final order:    X=acq1H Y=13Cz    Z=indir1H A=13Ca.
#   The scheme processes (acq1H,indir1H), then 13Cz, then 13Ca.
#   "EXT -time" clips padding added by Bruker to each 1D FID.

echo 'EXPERIMENT X:Hadq Y:Hind Z:Cz A:Ca'
echo '-------------------processing plane XY [x,TP,z]'
echo '>>>>(Hadq:Hind:Cz:Ca)'

xyz2pipe -in ./data/test%02d%03d.fid   -x \
| nmrPipe -fn POLY -time                             \
| nmrPipe -fn SP  -off 0.45 -end 0.95 -pow 2 -c 0.5 \
| nmrPipe -fn ZF  -size 1024                         \
| nmrPipe -fn FT    -verb                                  \
| nmrPipe -fn PS  -p0 150.6 -p1 -16.8              \
| nmrPipe -fn EXT -x1 4.8ppm -xn 0.0ppm  -sw -di    \
| nmrPipe -fn TP   -verb                                 \
| nmrPipe -fn SP  -off 0.45 -end 1.0 -pow 2  -c 0.50 \
| nmrPipe -fn ZF  -size 128                         \
| nmrPipe -fn FT   -verb                                 \
| nmrPipe -fn PS  -p0  0.0  -p1  0.0                  \
| nmrPipe -fn EXT -x1 4.8ppm -xn 0.0ppm  -sw -di    \
| nmrPipe -fn TP   -verb                                 \
| nmrPipe -fn POLY -auto                             \
| nmrPipe -fn TP   -verb                                 \
| pipe2xyz -out ft10/c13c13noe%02d%03d.DAT -z -ov

 
echo '<<<<<<(Hadq:Cz:Hind:Ca)'
echo '  '
echo '-------------------processing plane Z [z]'


xyz2pipe -in ft10/c13c13noe%02d%03d.DAT -y -verb      \
| nmrPipe -fn SP -off 0.5 -end 0.95 -pow 2  -c 1.0  \
| nmrPipe -fn ZF -size 64                           \
| nmrPipe -fn FT -verb                                   \
| nmrPipe -fn PS  -p0 -90  -p1 180  -di             \
| pipe2xyz -out ft10/c13c13noe%02d%03d.DAT -y -ov -inPlace

echo '<<<<<<(Hadq:Cz:Hind:Ca)'  
echo '  '
echo '-------------------processing plane A [a,y]  LP  '
# hay un warnning necsitas poner menos valores para la LP max 7 
xyz2pipe -in ft10/c13c13noe%02d%03d.DAT -a -verb     \
| nmrPipe -fn LP -fb                               \
| nmrPipe -fn SP -off 0.5 -end 0.95 -pow 2  -c 1.0 \
| nmrPipe -fn ZF -size 64                          \
| nmrPipe -fn FT  -verb                                 \
| nmrPipe -fn PS  -p0 -90  -p1 180  -di            \
| pipe2xyz -out ft11/c13c13noe%02d%03d.DAT -y -ov 

echo '<<<<<<(Hadq:Ca:Cz:Hind)'  
echo '-------------------reprocessing plane Z [z,z]  LP  '
 

xyz2pipe -in ft11/c13c13noe%02d%03d.DAT -z -verb     \
| nmrPipe -fn HT -auto                             \
| nmrPipe -fn PS -inv -hdr                         \
| nmrPipe -fn FT -inv                              \
| nmrPipe -fn ZF -inv                              \
| nmrPipe -fn SP -inv -hdr                         \
| nmrPipe -fn LP -fb                               \
| nmrPipe -fn SP -hdr                              \
| nmrPipe -fn ZF -size 64                             \
| nmrPipe -fn FT                                   \
| nmrPipe -fn PS -hdr -di                          \
| pipe2xyz -out ft11/c13c13noe%02d%03d.DAT -z -ov -inPlace


xyz2pipe -in ft11/c13c13noe%02d%03d.DAT  -verb     \
| pipe2xyz -out hhcc_complex_order1_good1_lp.nv -nv -ov -verb