;ft1d.mac
; Biosym Felix 2.3 
; macro for 1d processing of Bruker DMX data (digital filters)
; W. M. Westler
cl
get 'file ' datfil
get 'DECIM (from acqus)' decim
start:
get 'Is DECIM a power of 2? (y,n)' yesno
;
; # shift points calculated from DECIM parameter in acqus file
; #points = (70.5 - 15.5/DECIM)  for DECIM a power of 2
; #points = (185/3 - 15.5/DECIM)  for DECIM not a power of 2
; cshift = trunc(points)
; Residual first order phase correction is (points-cshift) * 360 degrees 
;
def bool 0
def ph0 &phase0
if &yesno eqs y then
eva points (70.5-15.5/&decim)
eva cshift (int(&points))
eva frstord (&points-&cshift)
eva correct (&frstord*360)
def phase0 &ph0
def phase1 &correct
eva bool 1
else
if &yesno eqs n then
eva points (185/3-15.5/&decim)
eva cshift (int(&points))
eva frstord (&points-&cshift)
eva correct (&frstord*360)
def phase0 &ph0
def phase1 &correct
eva bool 1
eif
eif
if &bool eq 0 start
get 'no (0), em (1), or qsin(2) ' fcn
if &fcn eq 0 then
go cont
eif
if &fcn eq 1 then
get 'line broadening' lbroad
go cont
eif
get 'qsin shift ' qsinsh
cont:
rn &datfil
csl &cshift
def temp &datsiz
eva datsiz (&temp-&cshift)
bc .2
if &fcn eq 0 then
go cont1
eif
if &fcn eq 1 then
em
go cont1
eif
ss &datsiz &qsinsh
cont1:
def datsiz &temp
csr &cshift
eva zfsize (&datsiz*2)
zf &zfsize
csl &cshift
ft
ph
dr
end