;CT-HMQC-J with water flip-back and composite proton 180-degree pulse.
;3J(HnHa) from set of J-modulated CT-HMQC spectra.
;Andy C. Wang and Ad Bax, November 1995.
;Kuboniwa, Grzesiek, Delaglio, Bax, J. Biomol. NMR, 4, (1994), 871-878.
;BMRB Pulse Sequence Accession Number: 27
;_______________________________________________________________________________
#include "bits.sg"
#define NITROGEN
;_______________________________________________________________________________
;PROTON:
  ;p1	proton 90-degree pulse at hl1=3 dB
  ;p2	water flip-back pulse at hl1=3 dB

;NITROGEN:
  ;p7	high power N15 90-degree pulse on f3
  ;p31	low power N15 90-degree pulse (190us) on f3 at dbl0
  ;nitrogen incrementation
  ;in20=in21=1/(4sw)

;DELAYS:
  ;d7=de
  d8=aq
  d11=50m
  d12=10m
  d13=p1*2.11+2u
  ;d20= 1/4 of HN->HA transfer time
  d21=d20
;_______________________________________________________________________________
100u  RESET
;
  ze
2 d11
  d12
3 d12*4
4 10u dbo do
;*****	presaturation	*****
  10u
  d1 hl1 dbhi dlo
  12.5m HIGH(11)        ;lock off
 (p1 ph1):f1
  2u
  GRAD( 20, POSITIV, 20)
  4.35m
;***** HMQC to N
  (p7 ph2):f3
  d13
  2u
  GRAD( 30, POSITIV, 10.0)
  d20
  (p7*2 ph8):f3 
  2u
  GRAD( 40, POSITIV, 10.0)
  d21
  p7*0.636:c8
  (p1 ph0 2u p1*2.22 ph3 2u p1 ph0):f1      ;composite 180-degree pulse
  p7*0.636:c8
  GRAD( 50, POSITIV, 10.0)
  2u
  d21 
  (p7*2 ph10):f3 
  2u
  GRAD( 60, POSITIV, 10.0)
  d20
  d13
  (p7 ph4):f3
  2u
  GRAD( 70, POSITIV, 20)
  4.35m
  (p1 ph5):f1
  2u
  GRAD( 80, POSITIV, 12)
  2m dblo dbl0
  (p1 ph6):f1
  90u
  (p2 ph7):f1      ;water flip-back pulse
  go=2 ph31 cpdb
  1m LOW(11)       ;lock on
  1m dbo
  d11 wr #0 if #0 zd
  d12 ip2
  lo to 3 times 2
  d12 id21
  d12 dd20
  d12 ip31
  d12 ip31
  lo to 4 times l3
do
dbo
exit

ph0=0
ph1=0 2
ph2=0 0 2 2
ph3=1
ph4=0
ph5=2 0
ph6=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3 
ph7=(360)180 180 180 180 270 270 270 270 0 0 0 0 90 90 90 90
ph8=PHASE_16(0)
    PHASE_16(2)
ph10=0
ph31=0 0 2 2 1 1 3 3 2 2 0 0 3 3 1 1