;hnhbgr.bv
; Bruker DMX Avance, XwinNMR version
; gradient version
;Use with hn(co)hb to get hb stereoassignments
;and chi-1 angles in 15N-labeled proteins
;Ref Archer et al., (1991) JMR 95,636-641
;use with hnhbrefgr.bv as reference
;for quantitation of J3HN-HB
;gradient version implemented by
;Brian Volkman, volkman@nmrfam.wisc.edu
;9/27/95
;BMRB Pulse Sequence Accession Number: 30

;use grdprog bvhnhb - see below

;p1 1H 90
;p2 15N 90 Hipower
"p15=1m"
"p16=3m"
"p17=1m"
"p18=0.5m"
;p21=0.5m
;p22=2m
;p31 15N 90 for GARP


;d1= 600m
"d2=2.3m"
"d3=27m"
"d5=d3-d13-p16-d16"
"d6=d3-d13-p16-d16+(p1*2)+6u"
"d10=3u"
"d11=50m"
"d12=20u"
"d13=3u"
"d16=300u"
"d22=d2-d13-p18"
"d26=p2-p1"

;l4=td2/2=complex 1H points
;l6=td1/2=complex 15N points

#include <Avance.incl>
#include <Gradfa.incl>

1 d12 ze	
   d12 pl1:f1	;1H high power
2 d11
   d11
3 d11
   d11        
4 d11
   d11
5 d11
   d11
6 d12 do:f2	;15N decoupling off
  d12 pl2:f2
  d12 LOCKH_OFF
  d1
;
; *** Inept to 15N ***
;
  (p1 ph0):f1
  d13
  p21 ph5
  d2
  (d26 p1*2 ph0):f1 (p2*2 ph1):f2
  d2 LOCKH_ON
  p22 ph0   ;messerele spin H2o suppression
  d13
  (p1 ph1):f1
  d13
  GRADIENT15(cnst25)
  d16 
  (p2 ph4):f2
;
; *** 15N evolution (t2) ***
;
  d10	
  (p1*2 ph0):f1
  d10
;
; *** HMBC to HB, t1 ***
;
  d13
  GRADIENT16(cnst26) 
  d16
  d5
  (p1 ph2):f1
  d0
  (p2*2 ph3):f2
  d0
  (p1 ph0):f1
  d13 
  GRADIENT16(cnst26) 
  d16
  d6
;
;*** Reverse inept to 1H ***
;
  (p2 ph0):f2
  GRADIENT17(cnst27) ;cnst27 negative
  d16
  (p1 ph0):f1
  d13
  GRADIENT18(cnst28)
  d22
  (d26 p1*2 ph0):f1 (p2*2 ph0):f2
  d13
  GRADIENT18(cnst28)
  d22 pl16:f2
  (p1 ph0):f1
  go=2 ph31 cpd2:f2
  d11 wr #0 do:f2 if #0 zd
  d11 ip2
  lo to 3 times 2
  d11 ip31*2
  d11 id0
  lo to 4 times l4
  d11 rd0
  d11 ip4
  lo to 5 times 2 	
  d11 ip31*2 
  d11 id10   
  lo to 6 times l6	
  LOCKH_OFF
exit

ph29=0
ph0=0
ph1=1 3
ph2=0 0 0 0 2 2 2 2  
ph3=0 0 1 1  
ph4=0
ph5=1
ph7=3
ph31=0 2 2 0 2 0 0 2

;***bvhnhb.r***
;loop ns
;{
;p15 { (0) | (0) | (0)+(cnst25) }
;    { (0) | (0) | (0)          }
;p16 { (0) | (0) | (0)+(cnst26) }
;    { (0) | (0) | (0)          }
;p16 { (0) | (0) | (0)+(cnst26) }
;    { (0) | (0) | (0)          }
;p17 { (0) | (0) | (0)+(cnst27) }
;    { (0) | (0) | (0)          }
;p18 { (0) | (0) | (0)+(cnst28) }
;    { (0) | (0) | (0)          }
;p18 { (0) | (0) | (0)+(cnst28) }
;    { (0) | (0) | (0)          }
;}